*****************************
*
* ODDS AND ENDS
*
*****************************
*
CEIL EQU $8EF 
WATEROOM EQU $9F6
DRAWBLUELINE EQU $5A42 
DRAWLINE EQU $5A48
ERASELINE EQU $5A45 
LEVSETTER EQU $520C
STREAM EQU $5A54
GPFLG EQU $9EB
WATLEV EQU $8DB 
LEV EQU $8CA
TIM1 EQU $9EA
XH EQU $9C3
BLOCKFLG EQU $9F9
XR EQU $9D8
BLOCK EQU $5A4E
MUY EQU $94CA
SHRINKROOMA EQU $9F7
SHRINKROOMB EQU $9F8
FAUCET EQU $5A51
SHRINKSFLG EQU $9FA
XLF EQU $9FB
XRT EQU $9FC
PERLEV EQU $9FD
SPRET EQU $5715
TEMP EQU $8D4
TEMP3 EQU $8E6
MSG EQU $5718
RNUM EQU $8C9
*
 ORG $5000
*
*
BLUB JMP RAISEWATER
SHRINKA JMP SHRINKA1
SHRINKB JMP SHRINKB1
SPRMA JMP SPRMA1
SPRMB JMP SPRMB1
SPRMC JMP SPRMC1
SPRMD JMP SPRMD1
*
*
RAISEWATER LDA LEV
 CMP #2
 BNE RAISEOUT
 BIT BLOCKFLG
 BMI SETA
 LDA XH
 CMP #8
 BCC RAISEOUT
 LDA #$80
 STA BLOCKFLG
 LDA #$F
 JSR MSG
 LDA #0
 STA XR
 STA TIM1
 JMP BLOCK
SETA BIT BLOCKFLG
 BVS SETA1
 LDA TIM1
 BNE RAISEOUT
 LDA #$40
 ORA BLOCKFLG
 STA BLOCKFLG
 JMP STREAM
SETA1 LDA TIM1  
 BNE RAISEOUT
 LDA #$20 
 STA TIM1
 LDY WATLEV
 JSR DRAWBLUELINE
 DEC WATLEV
 BNE RAISEOUT
 INC WATLEV
RAISEOUT RTS
*
*
SPRMA1 JSR FAUCET
 LDA #$80
 STA WATEROOM
 STX TEMP
 LDX RNUM
 LDA #8
 STA $9500,X
 LDX TEMP
 LDA #0
 STA TEMP
 STA TEMP3
 JMP SPRET
*
*
SPRMB1 LDA #$80
 STA SHRINKROOMA
 LDA #0
 STA TEMP
 STA TEMP3
 JMP SPRET
*
*
SPRMC1 LDA #$80
 STA SHRINKROOMB
 LDA #3        
 STA CEIL 
 LDA #0
 STA TEMP
 STA TEMP3
 JMP SPRET
*
*
SHRINKA1 BIT SHRINKSFLG 
 BPL NOTCLOSED
 BVC NOTCLOSED
SHRINKIT LDA TIM1
 BNE NOSHR
 LDA #$40
 STA TIM1
 LDA XLF
 STA XR
 JSR BLOCK
 LDA XRT
 STA XR
 JSR BLOCK
 INC XLF
 DEC XRT
NOSHR RTS
NOTCLOSED LDA XH
 BIT SHRINKSFLG
 BMI CHRTSD
 CMP #6
 BNE CHRTSD 
 LDA #$80
 ORA SHRINKSFLG
 STA SHRINKSFLG
 LDA LEV
 STA PERLEV
 TAX
 LDA MUY,X
 STA CEIL
 LDA #0
 STA XLF
BLD STA XR
 LDA #$1E
 JSR MSG
 JMP BLOCK
CHRTSD BIT SHRINKSFLG
 BVS NOSHR
 CMP #30        
 BNE NOSHR
 LDA #$40
 ORA SHRINKSFLG
 STA SHRINKSFLG
 LDA #39
 STA XRT
 BNE BLD
*
*
SHRINKB1 BIT SHRINKSFLG
 BPL NOTCLOSED
 BVC NOTCLOSED  
 LDA TIM1
 BNE SHBOUT
 LDA #$10 
 STA TIM1
 LDY CEIL 
 JSR DRAWLINE
 INC CEIL
 LDA CEIL
 CMP #185
 BNE SHBOUT
 DEC CEIL
SHBOUT RTS
***************************
*
* SPECIAL ROOM SET-UPS
*
***************************
*
RTSTR EQU $5A33 
LFSTR EQU $5A36
XTEMP EQU $8C3
YTEMP EQU $8C4
TREADNUM EQU $8C6
XNEW EQU $FC4
XOLD EQU $FB4
TEMP2 EQU $8CF
*
*
*
SPRMD1 LDA #4 
 STA TREADNUM   
 LDA #$15
 STA XTEMP
 LDA #$30 
 STA YTEMP
 JSR LFSTR
 INC XTEMP
 JSR RTSTR
 DEC XTEMP
 JSR LFSTR
 LDA #2
 STA TREADNUM
 INC XTEMP
 JSR RTSTR
 RTS     
